在無(wú)線遙控領(lǐng)域，PT2262/2272是目前最常用的芯片之一，但由于芯片要求配對(duì)使用，在很大程度上影響了該芯片的使用，筆者從PT2262波形特征入手，結(jié)合應(yīng)用實(shí)際，提出軟件解碼的方法和具體措施。
一、概述
PT2262/2272是一種CMOS工藝制造的低功耗低價(jià)位通用編解碼電路，是目前在無(wú)線通訊電路中作地址編碼識(shí)別最常用的芯片之一。PT2262/2272最多可有12位(A0-A11)三態(tài)地址端管腳(懸空,接高電平,接低電平),任意組合可提供531441地址碼,PT2262最多可有6位(D0-D5)數(shù)據(jù)端管腳,設(shè)定的地址碼和數(shù)據(jù)碼從17腳串行輸出。
PT2262/2272必須用相同地址碼配對(duì)使用，當(dāng)需要增加一個(gè)通訊機(jī)時(shí)，用戶不得不求助于技術(shù)人員或廠家來(lái)設(shè)置相同地址碼，客戶自己設(shè)置相對(duì)比較麻煩，尤其對(duì)不懂電子的人來(lái)說(shuō)。隨著人們對(duì)操作的要求越來(lái)越高，PT2262/2272的這種配對(duì)使用嚴(yán)重制約著使用的方便性，人們不斷地要求使用一種無(wú)須請(qǐng)教專(zhuān)業(yè)人士，無(wú)須使用特殊工具，任何人都可以操作的方便的手段來(lái)彌補(bǔ)PT2262/2272的缺陷，這就是PT2262軟件解碼。
二、解碼原理
 上面是PT2262的一段波形，可以看到一組一組的字碼，每組字碼之間有同步碼隔開(kāi)，所以我們?nèi)绻脝纹瑱C(jī)軟件解碼時(shí)，程序只要判斷出同步碼，然后對(duì)后面的字碼進(jìn)行脈沖寬度識(shí)別即可。
2262每次發(fā)射時(shí)至少發(fā)射4組字碼，2272只有在連續(xù)兩次檢測(cè)到相同的地址碼加數(shù)據(jù)碼時(shí)才會(huì)把數(shù)據(jù)碼中的“1”驅(qū)動(dòng)相應(yīng)的數(shù)據(jù)輸出端為高電平和驅(qū)動(dòng)VT端同步為高電平。因?yàn)闊o(wú)線發(fā)射的特點(diǎn)，第一組字碼非常容易受零電平干擾，往往會(huì)產(chǎn)生誤碼，所以程序可以丟棄處理。
下面我們來(lái)仔細(xì)看一下PT2262的波形特征：
振蕩頻率 f=2*1000*16/Rosc(kΩ) kHz 其中Rosc為振蕩電阻 這里我們選用的是一種比較常用的頻率f≈10 kHz, Rosc=3.3MΩ(以下同)。下圖是振蕩頻率與碼位波形的對(duì)應(yīng)關(guān)系：同步碼頭波形：
PT2262有三種編碼：0，1，和懸空(表示為f)。
1、 數(shù)據(jù)“0”發(fā)送的碼位如：
2、 數(shù)據(jù)“1”發(fā)送的碼位如：
3、 數(shù)據(jù)“f”發(fā)送的碼位如： |  |
有了以上具體的波形，我們就可以進(jìn)行軟件解碼了。T2262每次至少發(fā)送4次編碼，首先我們可以通過(guò)檢測(cè)11ms寬度的同步碼頭，有碼頭才開(kāi)始進(jìn)行編碼解碼，無(wú)碼頭則繼續(xù)等待。當(dāng)收到碼頭時(shí)，還要檢測(cè)是否已經(jīng)收到過(guò)碼頭，若無(wú)，則丟棄第一次編碼的信號(hào)，以防止誤碼。
從編碼圖中可以看出，每一位碼字都是從低電平開(kāi)始到高電平，到低電平，再到高電平。為了檢測(cè)方便，在接收端我們把編碼信號(hào)進(jìn)行了180°倒相，使碼位開(kāi)始的上升沿轉(zhuǎn)化為下降沿，這樣當(dāng)我們使用MCS51系列單片機(jī)解碼時(shí)可使用中斷方式及時(shí)截獲編碼。從編碼圖中還可以看出，每一位碼字都可以分成兩段，我們以每段中的電平寬度來(lái)描述碼位：
碼位 第一段 第二段 數(shù)值表示 反碼表示
0 窄 窄 00 11
1 寬 寬 11 00
f 窄 寬 01 10
無(wú)效碼 寬 窄 10 01
軟件解碼方法1(反碼)：
從第一個(gè)下降沿開(kāi)始延時(shí)700us左右，檢測(cè)電平高低，記為A1，再檢測(cè)第二個(gè)下降沿，延時(shí)700us左右，檢測(cè)電平高低，記為A2，這樣一個(gè)碼位就可以譯出來(lái)了，連續(xù)檢測(cè)12個(gè)碼位。
軟件解碼方法2(反碼)：
從第一個(gè)下降沿開(kāi)始記時(shí)，并不斷檢測(cè)電平變化，一有電平變化，立即記錄電平寬度B1，再繼續(xù)記時(shí)直至出現(xiàn)第二個(gè)下降沿，記錄兩個(gè)下降沿的間隔B2，重復(fù)以上步驟，得到B3，B4，判斷B1，B2，B3，B4是否在各自允許的誤差范圍內(nèi)，是則保存B1，B3，譯出一個(gè)碼位，否則認(rèn)為誤碼，丟棄。連續(xù)正確檢測(cè)12個(gè)碼位。
兩種解碼方式各有優(yōu)缺點(diǎn)如下：
解碼方式 優(yōu)點(diǎn) 缺點(diǎn)
1 程序簡(jiǎn)單，CPU開(kāi)銷(xiāo)少 解碼精度差
2 程序復(fù)雜，CPU開(kāi)銷(xiāo)大 解碼精度較高
為了獲得較高的解碼精度，我們推薦使用方法2，以避免大量的干擾信號(hào)的誤解碼。
三、參考解碼軟件
;軟件解碼程序(仿真PT2272) ;
;晶體頻率為11.0592Mhz ;
;本程序中的時(shí)間定位關(guān)系只適用于接3.3M振蕩電阻的PT2262解碼 ;
;使用其它阻值電阻時(shí)，應(yīng)將定位時(shí)間按電阻比例縮放
;下面的程序中
;REM 為信號(hào)輸入端 ;
;RECEIVE 檢測(cè)到有效信號(hào)標(biāo)志位 ;
;ENABLE_DETE 連續(xù)按鍵標(biāo)志 ;
;3AH,3BH用作定時(shí)器 ; ;
;PT2262共12根地址線 ;
;31H,32H:接收的前8 位地址編碼 ;
;33H,30H:接收的后4 位地址編碼(若最后4位用作數(shù)據(jù)端，則只須讀第33H單元的內(nèi)容即可) ;
;當(dāng)用作數(shù)據(jù)端時(shí)，PT2262對(duì)應(yīng)腳懸空被認(rèn)為是低電平。
;地址數(shù)據(jù)說(shuō)明 ;
;以31H.0 和32H.0 為例 ;
; 懸空 : 31H.0=0 32H.0=1 ;
; 1 : 31H.0=1 32H.0=1 ;
; 0 : 31H.0=0 32H.0=0 ;
; 出錯(cuò) : 31H.0=1 32H.0=0 ; ; ;
; 說(shuō)明：為了能可靠檢測(cè)到有效信號(hào)，建議每次接收至少檢測(cè)3次，然后比較3次檢測(cè)值
;3次值相同才認(rèn)為收到了正確信號(hào)�？稍谥鞒绦蛑腥缦绿幚恚旱�1次檢測(cè)時(shí)調(diào)用REMOTE
;第2、3次檢測(cè)時(shí)調(diào)用REMOTES，請(qǐng)注意必需連續(xù)調(diào)用，否則得不到正確的數(shù)據(jù) ; ;
;注意：將T1設(shè)定為16位定時(shí)器，允許中斷，否則將導(dǎo)致接收數(shù)據(jù)錯(cuò)誤
REMOTE: CLR RECEIVE ; ;檢測(cè)50ms 內(nèi)有沒(méi)有編碼接收 ;
MOV 3AH,#55 ;
REMOTEA: MOV 3BH,#250 ;
REMOTEB: JB REM,REMOTE0 ;有碼發(fā)送則跳轉(zhuǎn)
DJNZ 3BH,REMOTEB ;
DJNZ 3AH,REMOTEA ;
REMOTE_END_1: CLR ENABLE_DETE ;
REMOTE_END: CLR REMOTING ;清除探頭檢測(cè)標(biāo)志
RET ;
REMOTE0: JB ENABLE_DETE,REMOTE_END_1;按鍵沒(méi)有放開(kāi)則返回
REMOTES: MOV 34H,#12 ;接收12位編碼 ;解碼 ; ;先找出接收碼的開(kāi)頭即10ms左右的高電平 ;
MOV TH1,#00H ; ;設(shè)置高電平時(shí)間為8~12ms ; ;檢測(cè)和等待8ms 的 低電平,70ms門(mén)限 ;
CLR T_OVER ;
MOV TL1,#00H ;
SETB TR1 ;
REMOTE1: MOV 3AH,#50 ;
REMOTE2: MOV 3BH,#25 ;
REMOTE3: JB REM,REMOTE1 ;
JB T_OVER,REMOTE_END ;
DJNZ 3BH,REMOTE3 ;
DJNZ 3AH,REMOTE2 ; ; ;等待在4ms 內(nèi)接收到的高電平 ;
CLR T_OVER ;
MOV TH1,#0F1H ;
MOV TL1,#0F0H ;
SETB TR1 ;
REMOTE_4: JB T_OVER,REMOTE_5 ;
JNB REM,REMOTE_4 ;
CLR TR1 ;
AJMP REMOTE6 ; ;超出12ms 接收錯(cuò)誤返回 ;
REMOTE_5: AJMP REMOTE_END ;
REMOTE6: MOV 3AH,#00 ; 等待550us 后采集接收信號(hào) ;
DJNZ 3AH,$ ; ;采集接收信號(hào)并記錄 ;
MOV C,REM ;
MOV A,33H ;
RLC A ;
MOV 33H,A ;
MOV A,31H ;
RLC A ;
MOV 31H,A ; ;等待第二個(gè)上升沿,限時(shí)1.5ms ;
CLR T_OVER ;
MOV TH1,#0FAH ;
MOV TL1,#099H ;
SETB TR1 ;
RM1: JB T_OVER,REMOTE_END ;
JB REM,RM1 ;
CLR TR1 ; ;
CLR T_OVER ;
MOV TH1,#0FAH ;
MOV TL1,#099H ;
SETB TR1 ;
RM2: JB T_OVER,REMOTE_END ;
JNB REM,RM2 ;
CLR TR1 ; ;等待550us 后采集接收信號(hào) ;
MOV 3AH,#00 ;
DJNZ 3AH,$ ;
MOV C,REM ;
MOV A,30H ;
RLC A ;
MOV 30H,A ;
MOV A,32H ;
RLC A ;
MOV 32H,A ; ;等待第二個(gè)碼值的上升沿 ;
CLR T_OVER ;
MOV TH1,#0FAH ;
MOV TL1,#099H ;
SETB TR1 ;
RM3: JB T_OVER,RM5 ;
JB REM,RM3 ;
CLR TR1 ; ;
CLR T_OVER ;
MOV TH1,#0FAH ;
MOV TL1,#099H ;
SETB TR1 ;
RM4: JB T_OVER,RM5 ;
JNB REM,RM4 ;
CLR TR1 ;
DJNZ 34H,REMOTE6 ; ;把接收的編碼左移4 位將8 位密碼放在同一字節(jié)上
MOV 34H,#4 ;
AJMP REMOTE7 ;
RM5: AJMP REMOTE_END ;
REMOTE7: CLR C ;
MOV A,33H ;
RLC A ;
MOV 33H,A ;
MOV A,31H ;
RLC A ;
MOV 31H,A ;
CLR C ;
MOV A,30H ;
RLC A ;
MOV 30H,A ;
MOV A,32H ;
RLC A ;
MOV 32H,A ;
DJNZ 34H,REMOTE7 ; ;把4 位數(shù)據(jù)編碼由高4 位移到低4 位上 ;
MOV A,33H ;
SWAP A ;
MOV 33H,A ;
MOV A,30H ;
SWAP A ;
MOV 30H,A ;
SETB ENABLE_DETE ;
SETB RECEIVE ; ;
AJMP REMOTE_END_1 ;
END;
四、硬件抗干擾
在無(wú)線通訊中使用單片機(jī)會(huì)對(duì)通訊系統(tǒng)造成嚴(yán)重的干擾，相信許多技術(shù)人員一定有過(guò)同樣的苦惱。如果硬件設(shè)計(jì)不當(dāng)，會(huì)造成原先硬件解碼時(shí)通訊距離為200米，而用軟件解碼后可能只有十幾米，因此解決硬件抗干擾問(wèn)題在很大程度上可減少軟件解碼的誤碼率。
1、收發(fā)模塊：早期常用的頻率為47MHz，在這種頻率下，很難有好的解決方法；建議采用目前國(guó)家允許無(wú)線遙控使用的頻率315 MHz。
2、單片機(jī)振蕩頻率：大量的MCS51教材中推薦大家使用的是12 MHz及11.0592MHz的晶體，這些晶體在一般場(chǎng)合使用沒(méi)有問(wèn)題，但在此卻不可以，它們?cè)?00MHz左右仍然能夠產(chǎn)生較大的干擾，為解決單片機(jī)運(yùn)行速度與電磁干擾的矛盾，建議采用頻率為4MHz或3.58MHz的晶體。
3、隔離：為了有效抑制單片機(jī)對(duì)接收模塊的電磁干擾，建議采用①電源隔離；②端口隔離；端口隔離可采用三極管或比較器。實(shí)踐表明采用隔離的效果非常明顯。
五、結(jié)束語(yǔ)
PT2262的軟件解碼在實(shí)際應(yīng)用中有較好的用武之地。采用軟件解碼的系統(tǒng)，廠家再也無(wú)須對(duì)收發(fā)設(shè)備進(jìn)行配套，以利于生產(chǎn)于保管；對(duì)客戶來(lái)說(shuō)，使用軟件解碼無(wú)須求助，廠家只須再軟件中加入自動(dòng)學(xué)習(xí)功能，用戶可自行使用該功能，只須輕按學(xué)習(xí)鍵即可學(xué)習(xí)新的通訊設(shè)備，如遙控器等。目前，該軟件解碼已經(jīng)在某無(wú)線報(bào)警設(shè)備中采用，客戶反映使用簡(jiǎn)便，效果良好。 |
|
66821730(技術(shù)支持)
