多字節(jié)二進(jìn)制除法

被除數(shù)為3 個(gè)字節(jié)，在0x20、0x21、0x22 單元中，0x22.7 為最高位，0x20.0 為最低位。

除數(shù)為2 個(gè)字節(jié)，在0x30、0x31 中。

算法：EM78 單片機(jī)沒(méi)有除法指令，而且本例中除法為多字節(jié)除法，可采用如下算法。

將被除數(shù)擴(kuò)充一個(gè)字節(jié)0X23，0X23 清0。被除數(shù)左移1 位，0X23、0X22 中數(shù)據(jù)減去0X31、0X30 中數(shù)據(jù)，夠

減則減且0X20.0 置1，減出結(jié)果存入0X23、0X22；不夠減則0X23、0X22 保持不變，0X20.0 清0。然后被除數(shù)

再左移1 位，重復(fù)上述過(guò)程。共循環(huán)16 次，最后0X23、0X22 中得相減余數(shù)，0X21、0X20 中得商。注意，若

被除數(shù)左移后C 標(biāo)志為1，則不比較0X23、0X22 與0X31、0X30 數(shù)據(jù)大小關(guān)系而直接相減。

main： MOV a,@0x55 ;被除數(shù)賦值

MOV 0x20,a

MOV 0x21,a

MOV 0x22,a

MOV a,@0x0 ;被除數(shù)擴(kuò)充1 字節(jié)并清0

MOV 0x23,a

MOV a,@0x12 ;除數(shù)賦值

MOV 0x30,a

MOV 0x31,a

MOV a,@0x10 ;循環(huán)次數(shù)為16

MOV 0x32,a

again: call rt_sub ;調(diào)移位除法子程

djz 0x32 ;16 次循環(huán)完成則結(jié)束

jmp again ;未完成則繼續(xù)

self: jmp self

rt_sub:

bc 0x03,0 ;c 標(biāo)志清0

rlc 0x20 ;被除數(shù)左移1 位

rlc 0x21

rlc 0x22

rlc 0x23

jbc 0x03,0

jmp rt3 ;c標(biāo)志為1 則直接相減

MOV a,0x23 ;c 標(biāo)志為0 則先比較大小

MOV 0x25,a

MOV a,0x22

MOV 0x24,a

MOV a,0x31 ;先比較高位

sub 0x25,a

jbc 0x03,2

jmp rt1 ;高位相等跳rt1 比較低位

jmp rt2 ;高位不等跳rt2

rt1: MOV a,0x30 ;比較低位

sub 0x24,a

jbc 0x03,2

jmp rt3 ;低位也相等則跳rt3,相減,上1

rt2: jbs 0x03,0

ret ;減數(shù)大則返回,減數(shù)小則相減,上1

rt3: bs 0x20,0 ;上1

call sub_2b ;調(diào)2 字節(jié)減法子程

ret

sub_2b:

MOV a,0x31 ;高字節(jié)相減

sub 0x23,a

MOV a,0x30 ;低字節(jié)相減

sub 0x22,a

jbc 0x03,2

ret ;低字節(jié)相等,無(wú)借位,返回

jbc 0x03,0

ret ;無(wú)借位,返回

dec 0x23 ;低字節(jié)相減有借位,高字節(jié)結(jié)果減1

ret

eop